#sh "when you claim your mount from the stable.. this automatically writes its name to variable mount_riding"
#TRIGGER {^(%w), * is retrieved from stall %d and handed over to you.$} {#var mount_riding %lower("%1")}

#sh " this marks up which mount you are riding to mount_riding"
#TRIGGER {^You get up * (%w) and begin to ride.$} {#var mount_riding %lower("%1");#var mount 1}

#sh "when monster knocks you off your mount, this automatically leads the mount... leads the mount in @mount_riding"
#TRIGGER {^You are knocked off your mount!$} {#sub {%trigger %ansi(bold,green)>> KNOCKED OFF FROM MOUNT};lead @mount_riding}

#sh "another similar message... automatically leads it"
#TRIGGER {^Your mount throws you!} {#sub {%trigger %ansi(bold,green)>> KNOCKED OFF FROM MOUNT};lead @mount_riding}

#sh " marks up the time when protect mount is casted... protect mount lasts max 60 minutes"
#TRIGGER {^* is surrounded by a shimmering white aura which quickly fades.$} {#var protect_mount_timer %eval(%time(dd)*24*3600+%time(hh)*3600+%time(nn)*60+%time(ss))}

#sh " protect mount off"
#TRIGGER {^Your protection spell on * has worn off.$} {timer protect_mount_timer;#sh >> PROTECT MOUNT OFF > @timed}

#sh " @mount_stall is a list of mounts which are outside of the stall atm... its a reminder you don't forget"
#sh " to store them back... this also 0's the mount feed timer"
#TRIGGER {^(%w), * is retrieved from stall ? and handed over to you.$} {#additem mount_stall %1;#var feed_mount_timer %eval(%time(dd)*24*3600+%time(hh)*3600+%time(nn)*60+%time(ss))}

#sh " first login of the day after boot... this nulls mount_stall"
#TRIGGER {^Moving to starting location.$} {#var prots %null;#var eskin_count 0;#var mount_stall %null;#var mantle_count 0}

#sh " removes a mount from the @mount_stall reminder list"
#TRIGGER {^(%w), * has been stored in stall ?.$} {#delitem mount_stall %1}

#sh " just a highlight"
#TRIGGER {You are now off your mount.} {#sub {%trigger %ansi(bold,green)>> OFF YOUR MOUNT};#var mount 0}

#sh " @your_mounts is a variable with all the names of my mounts... "
#sh " when i see my mount without it being ridden or lead, this trigger automatically leads it"
#TRIGGER {^(%w), the * {crab|bear|chimera|drake|griffon}$} {#if (%pos(%lower("%1"),@your_mounts)!=0) {lead %lower("%1")}}

#sh " same as previous"
#TRIGGER {^(%w), the * {crab|bear|chimera|drake|griffon} ~<protected~>$} {#if (%pos(%lower("%1"),@your_mounts)!=0) {lead %lower("%1")}}

#sh " just a highlight"
#TRIGGER {^You begin to lead } {#co blue}

#sh " if i type ride <mount> and there a fight going on... this leads it"
#TRIGGER {^You cannot start riding while in combat!} {lm}

#sh "when mount, which is in my @your_mounts list appears, this automatically leads it"
#TRIGGER {^(%w) appears instantly.$} {#if (%pos(%lower("%1"),@your_mounts)!=0) {lead %lower("%1")}}

#sh " this nulls the feed timer"
#TRIGGER {^You feed * who eats it.$} {#var feed_mount_timer %eval(%time(dd)*24*3600+%time(hh)*3600+%time(nn)*60+%time(ss))}

#sh " this reminds every 30 minustes or so which mounts are outside the stable... just a reminder"
#ALARM {-30:00} {#if (@mount_stall!=%null) {#SH %ansi(red,blink)>>>>>>>>> ALL MOUNTS ARE NOT CHESTED @mount_stall}}

#sh " automatical lead"
#TRIGGER {^The ice makes a sound below your mount, scaring it!} {lead @mount_riding}


#sh "a highlight"
#TRIGGER {^{@your_mounts} panics and attempts to flee.} {#sub {%line %ansi(cyan,bold,blink)>> LÄHTI JUOKSEEN KARKUUN!}}

#sh " 'pm' casts protect mount at @mount_riding... 'pm bear' casts it to bear"
#ALIAS pm {#if ("%1"=%null) {cast protect mount at @mount_riding} {cast protect mount at "%-1"};#if (@mount=1) {dm;#Sh %ansi(bold,red)>> %ansi(bold,white,blink)DISMOUNT! %ansi(bold,red)<<<>;#Sh %ansi(bold,red)>> %ansi(bold,white,blink)DISMOUNT! %ansi(bold,red)<<<>;#Sh %ansi(bold,red)>> %ansi(bold,white,blink)DISMOUNT! %ansi(bold,red)<<}}

#sh " basic alias that makes storing mount easyer... removes noeq from it too"
#ALIAS store {dismount mount;release;get noeq from %-1;release;~store %-1;blook}

#sh " 'sm' summonts mount at @mount_riding, 'sm sulla' summons mount nammed 'sulla'"
#ALIAS sm {lead mount;#if ("%1"=%null) {cast summon mount at @mount_riding} {cast summon mount at %-1}}

#sh " 'hm' casts heal mount at mount in @mount_riding, 'hm bear' casts it to bear"
#ALIAS hm {#if ("%1"=%null) {cast heal mount at @mount_riding;scan @mount_riding} {cast heal mount at %-1;scan %-1}}

#sh " 'rm' releases the mount(if you are leading it) and tries to ride it... if you are unable to ride,"
#sh " my triggers should lead it automatically"
#sh " 'rm' tries to ride mount in @mount_riding, 'rm bear' tries to ride bear"
#ALIAS rm {release;#if ("%1"=%null) {ride @mount_riding;scan @mount_riding} {ride "%-1";scan "%-1"}} "mount"

#sh " feeds corpse to @mount_riding"
#ALIAS fec {get corpse;feed corpse to @mount_riding} "corpse"

#sh " 'dm' dismounts you from your mount and immediately leads mount in @mount_riding"
#sh " 'dm fdsfds'(fdsfds can be anything) dismounts you from your mount and RELEASES the mount... "
#sh " purpose of 'dm fdsfds' is to leave your mount behind"
#ALIAS dm {#if ("%1"=%null) {dismount mount;lead @mount_riding} {dismount mount;release @mount_riding}}

#sh " automatically leads mount in @mount_riding"
#ALIAS lm {lead @mount_riding;scan @mount_riding}

#sh " automatically dismount, refuels fire, and starts riding mount in @mount_riding"
#ALIAS rr {dismount mount;refuel;ride @mount_riding}

#sh " general alias i use... this shows when i last casted protect mount and when i last fed my mount... also has some other stuff in it too"
#ALIAS tich {#var temp %null;#var temp2 %null;timer feed_mount_timer;#sh {>> MOUNT FEED     > %ansi(bold,green)@timed};timer protect_mount_timer;#sh {>> PROTECT MOUNT  > %ansi(bold,green)@timed};timer melodical_embracement_timer;#sh %ansi(bold,green)¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤¤;#sh {>> MELODICAL EMBRACEMENT > %ansi(bold,green)@timed};#if (@prots) {#forall @prots {timer %i"_timer";#var temp {@temp%replace( %i, "_", " ")@timed }};#var temp %replace(@temp, "[", "");#var temp %replace(@temp, "]", "")};#if (@prots) {#forall @prots {#var temp2 {@temp2%replace( %i, "_", " ")" "}}};#var temp2 %replace(@temp2, "[", "");#var temp2 %replace(@temp2, "]", "");#if ("%1"=%null) {#sh %ansi(blue)prots>%ansi(bold,white)%if(@unstun_temp=2,"Uns ",,)@temp%if(@eskin_count>0, ES(@eskin_count),"")%if(@mantle_count>0, VM(@mantle_count),"")} {#if ("%2"=%null) {#send {party say >%if(@unstun_temp=2,"Uns ",,)@temp2%if(@eskin_count>0, ES(@eskin_count),"")%if(@mantle_count>0, VM(@mantle_count),"")}} {#send {party say >%if(@unstun_temp=2,"Uns ",,)@temp%if(@eskin_count>0, ES(@eskin_count),"")%if(@mantle_count>0, VM(@mantle_count),"")}}};#var temp3 @temp2} "<none>"

#sh " brings mount into ship through hatch"
#ALIAS hatchi {ship secure;console height 1;console height 10;console water 1;console water 10;console air 1;console air 10;helm;console info;hoho;case;view;plank fdsfds;paths;map;sailor signal ironclad;pursue;gangway w;gangway e;gangway s;gangway n;gangway sw;gangway se;gangway ne;gangway nw;gangway raise;rescue ironclad;d;open hatch;hatch;ride @mount_riding;pff;ironclad;close hatch;u}

#sh " brings mount out of the ship"
#ALIAS hatcho {rescue ironclad;ship secure;pff;d;open hatch;hatch;dismount @mount_riding;release;rescue ironclad;d;close hatch;u;jump overboard;lead @mount_riding}

#sh " here i have added the name of all my mounts... if i see a mount from this list and its NOT"
#sh " being led or ridden, i automatically lead it... if i summon a mount from this list, i automatically"
#sh " lead it"
#VAR your_mounts {kalu|molo|piru|xyra|paha|tuho|pora|tuska|rauli|manalainen|druga|death|rage|feuerhauch|rauta|crimson|hate|tappaja}


#sh " mount related variables"
#VAR protect_mount_timer {30}
#VAR mount_riding {tappaja}
#VAR mount_active {tuhooja}
#VAR mount_stall {}
#VAR mount {0}
#VAR feed_mount_timer {432}

#sh " some class"
#CLASS {mount}

#sh " basic timer function i use"
#ALIAS timer {#var time @%1;#math timer_passed (%eval(%time(dd)*24*3600+%time(hh)*3600+%time(nn)*60+%time(ss))-@time);#math timer_h @timer_passed/3600;#math timer_m (@timer_passed-@timer_h*3600)/60;#math timer_s @timer_passed-@timer_h*3600-@timer_m*60;#if (%len( @timer_h)=1) {#var timer_h 0@timer_h};#if (%len( @timer_m)=1) {#var timer_m 0@timer_m};#if (%len( @timer_s)=1) {#var timer_s 0@timer_s};#var timed "%char(91)"%if( @timer_h!=0, @timer_h":")%if( @timer_m!=0, @timer_m":", "00:")%if( @timer_s!=0, @timer_s, "00")"%char(93)"} "<none>"

#sh " this reminds me to cast protect mount to my mount when abigail is nd.. cant remember reason anymore :D"
#TRIGGER {^Abigail, the abbess is near death.} {#sh MUISTA TAIKOA PROTECT MOUNTTI MOUNTTIIN!;#sh MUISTA TAIKOA PROTECT MOUNTTI MOUNTTIIN!;#sh MUISTA TAIKOA PROTECT MOUNTTI MOUNTTIIN!;#sh MUISTA TAIKOA PROTECT MOUNTTI MOUNTTIIN!;#sh MUISTA TAIKOA PROTECT MOUNTTI MOUNTTIIN!;#sh MUISTA TAIKOA PROTECT MOUNTTI MOUNTTIIN!;#sh MUISTA TAIKOA PROTECT MOUNTTI MOUNTTIIN!}

#sh " this is unsusable now... purpose of this is basically REMIND which mounts are out of the stable before you quit"
#ALIAS quit {~close all chest;look;ssps;#alarm +2 {#sh >> ALL BARD SPELLS @summa};quote 'date' party say;#if (@mount_stall!=%null) {~quit stop;#SH %ansi(red,blink)>>>>>>>>> ALL MOUNTS ARE NOT CHESTED @mount_stall} {~quit};#var prots %null} "<none>"